Resumen

DescripciónRegular polygon 19 annotated.svg	English: Regular enneadecagon with annotation.
Fecha	19 de julio de 2013, 12:24:44
Fuente	Trabajo propio
Autor	László Németh
Otras versiones	Regular 3-gon Regular 4-gon Regular 5-gon Regular 6-gon Regular 7-gon Regular 8-gon Regular 9-gon Regular 10-gon Regular 11-gon Regular 12-gon Regular 13-gon Regular 14-gon Regular 15-gon Regular 16-gon Regular 17-gon Regular 18-gon Regular 19-gon Regular 20-gon
SVG desarrollo InfoField	El código fuente de esta imagen SVG es válido.   Esta geometría fue creada con OpenOffice.org

; Created in LibreOffice 4 with this LibreLogo program.
; Usage: Copy it in an English language document in LibO Writer,
; and click on the Start icon of the View»Toolbar»Logo toolbar.

TO superior num prevnum
  s = “”
  FOR i IN STR num [
    s = s + “⁰¹²³⁴⁵⁶⁷⁸⁹”[INT i]
  ]
  IF NOT prevnum % 10 = 1 [ s = “ ” + s ] ; narrow space
  OUTPUT s
END

TO inferior num
  s = “”
  FOR i IN STR num [
    s = s + “₀₁₂₃₄₅₆₇₈₉”[INT i]
  ]
  OUTPUT s
END

CLEARSCREEN HIDETURTLE FONTSIZE 18 FONTFAMILY “DejaVu Sans”
FOR vertices IN [7, 11, 13, 14, 16, 17, 19] [
;    PICTURE “poly/regular_polygon_%d_annotated.svg” % vertices [ ; from LibO 4.1.1
    PICTURE [
        HOME FILLCOLOR “WHITE” PENCOLOR “SILVER” 
        PENDOWN PENSIZE 2 CIRCLE 400
        β = 360/vertices
        q = vertices // 4
        CIRCLE [80 + vertices * 14, 80 + vertices * 14, β * q, β * (q + 1)]
        FONTCOLOR “SILVER”
        IF vertices > 18 [ f = 0.004 ] [ f = 0.005 ]
        HEADING β * q + β * 0.5 PENUP
        FORWARD (80 + vertices * 14) * (0.3 + (f * vertices))
        HEADING 0
        s1 = superior (360 % vertices, 360 // vertices)
        s2 = inferior vertices
        LABEL “%d%s⁄%s°” % (β, s1, s2)
        HOME HEADING 0 PENDOWN
        dots = []
        REPEAT vertices [
                FORWARD 200
                where = POSITION
                dots = dots + [where]
                BACK 200 RIGHT β
        ]
        HOME PENSIZE 2 CIRCLE 10
        PENCOLOR “BLACK” FONTCOLOR “BLACK”
        α = ((vertices-2)/vertices)*180
        PENUP FORWARD 200 PENDOWN
        CIRCLE [100 + 105/vertices, 100 + 105/vertices, 180 – α/2, 180 + α/2]
        s1 = superior ((vertices-2) * 180 % vertices, INT α)
        PENUP BACK 20 + 70/vertices LABEL “%d%s⁄%s°” %  (α, s1, s2)
        HOME PENUP PENSIZE 4 PENUP
        FOR i IN dots + dots[0:1] [ POSITION i PENDOWN ] PENSIZE 2
        FOR i IN dots [ PENUP POSITION i PENDOWN CIRCLE 10 ]
    ]
]

Licencia

László Németh, titular de los derechos de autor de esta obra, la publica en los términos de la siguiente licencia:

Este archivo está disponible bajo la licencia Creative Commons Dedicación de Dominio Público CC0 1.0 Universal.

La persona que ha asociado una obra a este documento lo dedica al dominio público mediante la cesión mundial de sus derechos bajo la ley de derechos de autor y todos los derechos legales adyacentes propios de dicha, en el ámbito permitido por ley. Puedes copiar, modificar, distribuir y reproducir el trabajo, incluso con objetivos comerciales, sin pedir aprobación del autor. http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse